Результат функции

Нередко функции выполняют некоторые вычисления и генерируют некоторый результат этих вычислений. Вполне вероятно, что мы захотим передать этот результат во внешний код. Во многих языках программирования высокого уровня есть механизм возвращения результата функции - обычно для этого применяется оператор return. В ассемблере такого механизма нет. Наиболее удобным местом для возврата результатов функции в архитектуре x86-64 являются регистры.

Как правило, результат функции помещается в регистр RAX (или его подрегистры EAX, AX, AL), хотя в реальности, если мы сами пишем всю программу на ассемблере, мы можем использовать для этой цели любой регистр общего назначения. Однако на регистр RAX завязано много соглашений. Так, именно в RAX большинство языков высокого уровня помещают результат функции. А согласно интерфейсу System ABI прицелочисленный результат помещается в регистр RAX.

Если нужно вернуть результат, размер которого превышает 64 бита (например, 128 бит или 256 бит) и соответственно не помещается в RAX или в другой 64-разрядный регистр общего назначения, то можно разделить результат на части и вернуть эти части в двух или более регистрах. Часто можно увидеть, как функции возвращают 128-битные значения в паре регистров RDX:RAX. .

Если надо вернуть большой объект, например, массив из 1000 элементов, то, очевидно, регистры не подходят. И в этом случае можно вместо значения возвратить его адрес (который занимает 8 байт).

Простейший пример возвращения результата:

.globl _start 

.text
_start:
    # устанавливаем параметры для функции sum
    movq $5, %rdi
    movq $6, %rsi
    call sum            # после вызова в RAX - результат сложения
    movq %rax, %rdi     # помещаем результат в RDI

    movq $60, %rax
    syscall

# Процедура sum выполняет сложение двух чисел
# RDI - первое число
# RSI - второе число
# RAX - результат сложения
sum:
    movq %rdi, %rax
    addq %rsi, %rax
    ret

Здесь функция sum принимает через регистры RDI и RSI два параметра - два числа, складывает их и помещает результат в регистр RAX. После вызова функции sum мы можем использовать полученный результат в регистре RAX каким-нибудь образом, например, здесь копируем его в регистр RDI.

Другой пример найдем сумму чисел массива и поместим результат в RAX:

.globl _start 

.data
nums: .quad 10, 20, 30, 15, 15
len = (.-nums)/numSize
numSize=8
.text
_start:
    # устанавливаем параметры для функции sum
    movq $nums, %rdi                  # в RDI адрес массива
    movq $len, %rsi     # в RSI - количество элементов массива
    call sum            # после вызова в RAX - результат сложения
    movq %rax, %rdi     # помещаем результат в RDI

    movq $60, %rax
    syscall

# Процедура sum выполняет сложение чисел массива
# RDI - адрес массива
# RSI - размер массива
# RAX - результат сложения
sum:
    xorq %rax, %rax     # обнуляем RAX для хранения результата
    jmp while_condition # переходим к проверке условия
while_begin:
    decq %rsi
    addq (%rdi, %rsi, numSize), %rax    # складываем значение по адресу [rdi + rsi*numSize]
while_condition:
    cmpq $0, %rsi   # сравниваем количество обработанных элементов 
    jne while_begin # если не все элементы обработали, переходим обратно
    ret

Здесь функция sum принимает адрес массива и количество элементов в массиве. В цикле проходит пор всем элементам массива, используя косвенную адресацию и счетчик элементов - регистр RDI и помещает в регистр RAX сумму элементов массива.